(*
	IV окружной этап Всероссийской олимпиады школьников по информатике
	24 - 28 марта 2006 г.
	г. Петрозаводск

	Задача D. Операции
	Авторы: А. Чурюмов, А. Николаевский
	Решение: А. Лопатин
*)

{$O-,Q+,R+}
uses SysUtils, Math;


function gcd (a, b:int64):int64;
begin
  if b=0 then gcd:=a else gcd:=gcd (b, a mod b);
end;

function GetDigStr (var s:string):string;
begin
  Result:='';
  while (length (s)>0) and (s[1] in ['0'..'9']) do begin
    Result:=Result+s[1]; delete (S, 1, 1);
  end;
end;

function mystrtoint (const s:string):integer;
begin
  if s='' then Result:=0 else Result:=strtoint (s);
end;


procedure ReadNum (s:string; var p, q:int64);
var s1, s2, s3:string;
    p1, p2, p3, q1, q2:int64;
begin
  s1:=GetDigStr (s); assert (length (s1) in [1..3]);
  assert ((s1[1]<>'0') or (length (s1)=1));
  s2:=''; s3:='';
  if s<>'' then begin
    assert (s[1]='.'); delete (s, 1, 1);
    s2:=GetDigStr (s); assert (length (s2) in [0..3]);
    if s<>'' then begin
      assert (s[1]='('); delete (s, 1, 1);
      s3:=GetDigStr (s); assert (s=')'); assert (length (s3) in [1..3]);
    end;
  end;
  p1:=mystrtoint (s1); p2:=mystrtoint (s2); p3:=mystrtoint (s3);
  q1:=trunc (intpower (10, length (s3)+length (s2))-intpower (10, length (s2)));
  q2:=trunc (intpower (10, length (s2)));
  if q1=0 then q1:=q2;
  p:=p1*q1+p2*(q1 div q2)+p3;
  q:=q1;
end;

var p1, q1, p2, q2, p, q, g:int64;
    s1, s2:string;

begin
  reset (input, 'oper.in'); rewrite (output, 'oper.out');
  read (s1); assert (eoln and not eof); readln;
  ReadNum (s1, p1, q1);
  read (s2); assert (eoln and not eof); readln;
  ReadNum (s2, p2, q2);
  assert (eof);
  p:=p1*q2+p2*q1;
  q:=q1*q2;
  g:=gcd (p, q);
  p:=p div g;
  q:=q div g;
  assert (p>0);
  writeln (p, '/', q);
end.